1 'CuliCom: Menu-generator voor CP/M & MS-Dos
2 '
3 ' (c) by Horn-Soft BV
4 '        Herengracht 250
5 '        1016 BV  Amsterdam
6 '        Tel. 020-26 11 98
7 '
8 ' Laatste wijziging 20 nov 85 [NHH]
9 '
10 'Initialisatie:
15 QQ$="PIPOKOEIEN"
20 DEFINT A-Z:WIDTH LPRINT  255
30 FOR N=0 TO 5:PRINT:NEXT
31 PRINT"É"STRING$(76,"Í")"»":TB=19
32 PRINT"º"TAB(TB)" ÜÜÜÜ         Ü      ÜÜÜÜ              "TAB(78)"º"
33 PRINT"º"TAB(TB)"Û      Ü   Ü  Û  Ü  Û       ÜÜÜ   ÜÜÜÜ "TAB(78)"º"
34 PRINT"º"TAB(TB)"Û      Û   Û  Û  Û  Û      Û   Û  Û Û Û"TAB(78)"º"
35 PRINT"º"TAB(TB)"Û      Û   Û  Û  Û  Û      Û   Û  Û Û Û"TAB(78)"º"
36 PRINT"º"TAB(TB)"ßÜÜÜÜ  ßÜÜßÛ  Û  Û  ßÜÜÜÜ  ßÜÜÜß  Û Û Û"TAB(78)"º"
37 PRINT"º"TAB(78)"º"
38 PRINT"º"TAB(TB+13)"Menugenerator"TAB(78)"º"
40 PRINT"Ç"STRING$(76,"Ä")"¶"
43 PRINT"º   (c) Horn-Soft, Herengracht 250, 1016 BV  Amsterdam; Tel. 020 - 261198"TAB(78)"º"
45 PRINT"È"STRING$(71,"Í")"[1.0]¼"
46 FOR N=1 TO 6:PRINT:NEXT
50 IP$="Wat is de datum (Dg/Md/Jr)":GOSUB 920:IF LEN(A$)<>8 THEN 50
51 MND=VAL(MID$(A$,4,2)):IF MND<1 OR MND>12 THEN 50
52 DAG=VAL(LEFT$(A$,2)):IF DAG<1 OR DAG>31 THEN 50
53 JAAR=VAL(RIGHT$(A$,2)):IF JAAR<85 OR JAAR>99 THEN 50
54 RANDOMIZE MND*100+DAG
60 DRV$="":HFD$="HOOFD.REC":IGF$="INGREDIE.REC":GRF$="GROENTE.REC"
61 VRF$="VOOR.REC":NAF$="NA.REC":WNF$="WIJN.REC"
62 DIM NL(25),SZ$(4),FEC$(25)
63 FOR N=1 TO 4:READ SZ$(N):NEXT
64 DATA lente,zomer,herfst,winter
70 FOR N=1 TO MND:READ DATUM$:NEXT:FOR N=MND+1 TO 12:READ M$:NEXT
71 DATUM$=STR$(DAG)+" "+DATUM$+" 19"+RIGHT$(A$,2)
72 DATA januari,februari,maart,april,mei,juni,juli,augustus,september,oktober,november,december
75 FOR N=1 TO 25:READ FEC$(N):NEXT
76 DATA Rijst,Aardappelpuree,Gekookte aardappelen,Gebakken aardappelen
77 DATA Pommes parisiennes,Patat frites,Aardappelkroketten,,
78 DATA Bonen,Kastanjepuree,Chutney,,,,,,,,,,,,,
80 SZ=MND*100+DAG
81 IF SZ<321 THEN SZ=4:GOTO 90
82 IF SZ<621 THEN SZ=1:GOTO 90
83 IF SZ<921 THEN SZ=2:GOTO 90
84 IF SZ<1221 THEN SZ=3:GOTO 90
85 SZ=4
90 PRINT"@":PRINT
100 'Keuzelijst
110 PRINT"CuliCom Keuzelijst"STRING$(74-POS(0),"-")"[H-S]
111 PRINT:PRINT:PRINT:PRINT:PRINT
115 PRINT TAB(TB)"******************************************
116 PRINT
120 PRINT TAB(TB)"1. Menu kiezen naar hoofdingredient
130 PRINT TAB(TB)"2. Menu kiezen naar soort (vlees/vis/enz.)
190 PRINT TAB(TB)"0. Einde programma
195 PRINT
196 PRINT TAB(TB)"******************************************
197 PRINT
200 PRINT TAB(TB)"Wat is uw keuze ? (1/2/0)"
201 FOR N=1 TO 7:PRINT:NEXT
202 PRINT STRING$(78,"-")
210 IP$=INPUT$(1):IF IP$<"0"OR IP$>"2"THEN 210ELSE PRINT"@"
220 ON VAL(IP$)+1 GOTO 300,1000,2000
300 'Einde CuliCom
305 FOR N=1 TO 8:PRINT:NEXT
310 PRINT"Einde CuliCom"STRING$(74-POS(0),"-")"[H-S]
311 FOR N=1 TO 4:PRINT:NEXT
320 PRINT"Het programma CuliCom is beeindigd. Smakelijk eten!
321 FOR N=1 TO 4:PRINT:NEXT
330 PRINT STRING$(78,"-")
331 FOR N=1 TO 6:PRINT:NEXT
340 END
500 'Routines voor indeling afdruk
510 LPRINT:FOR N=1 TO 9:LPRINT"****    ";:NEXT:LPRINT"****"
511 LPRINT"* ";:FOR N=1 TO 9:LPRINT"  ****  ";:NEXT:LPRINT" *"
512 FOR M=1 TO 2:LPRINT" *"TAB(75)"*":NEXT
513 FOR M=1 TO 2:LPRINT"*"TAB(76)"*":NEXT
514 PRTL=6:PRTI=1:RETURN
520 LPRINT TAB(1+PRTI)"*"TAB(12)PRT$TAB(76-PRTI)"*"
521 PRTL=PRTL+1:IF PRTL MOD 2=0 THEN PRTI=1-PRTI
522 IF PRTL=50 THEN GOSUB 530:GOSUB 500
523 RETURN
530 FOR N=PRTL TO 53:LPRINT TAB(1+PRTI)"*"TAB(76-PRTI)"*"
531 IF N MOD 2=1 THEN PRTI=1-PRTI
532 NEXT
533 LPRINT" *"TAB(10)"CuliCom Menugenerator. (c) Horn-Soft BV Amsterdam.";
534 IF PRTP<>0 THEN LPRINT" Pagina"PRTP;:PRTP=PRTP+1
535 LPRINT TAB(75)"*":LPRINT" *"TAB(75)"*"
536 LPRINT"* ";:FOR N=1 TO 9:LPRINT"  ****  ";:NEXT:LPRINT" *"
537 FOR N=1 TO 9:LPRINT"****    ";:NEXT:LPRINT"****"
538 FOR N=1 TO 7:LPRINT:NEXT:RETURN
540 IF PRTL>39 THEN GOSUB 530:GOSUB 500
541 PRT$=STRING$(54,"-"):GOSUB 520:PRT$="":GOTO 520
550 OPEN"I",1,DRV$+FILE$:FOR NX=1 TO NL:LINE INPUT#1,NAAM$:NEXT:CLOSE 1
551 PRT$=MID$(NAAM$,2):PRT$=STRING$(27-LEN(PRT$)/2,32)+PRT$:GOSUB 520
552 PRT$="":GOTO 520
560 PRT$=STRING$(25,32)+"-==-":GOSUB 520:PRT$="":GOTO 520
600 'Afdrukken recept uit FILE$ vanaf regel NL
610 OPEN"I",1,DRV$+FILE$:FOR NX=1 TO NL-1:LINE INPUT#1,A$:NEXT
611 LINE INPUT#1,NAAM$:NAAM$=MID$(NAAM$,2):SP$=STRING$(25-LEN(NAAM$)/2,32)
612 PRT$=SP$+STRING$(LEN(NAAM$)+4,"+"):GOSUB 520
613 PRT$=SP$+"+ "+NAAM$+" +":GOSUB 520
614 PRT$=SP$+STRING$(LEN(NAAM$)+4,"+"):GOSUB 520
615 PRT$="":GOSUB 520
619 LINE INPUT#1,A$
620 LINE INPUT#1,IG$:IF ASC(IG$)=45 THEN CLOSE 1:RETURN ELSE IF ASC(IG$)<>64 THEN 630
621 GOSUB 800:PRT$=IG$:GOSUB 520:GOTO 620
630 PRT$="":GOSUB 520:TXT$=IG$:REST$=""
631 IF ASC(TXT$)=45 THEN 650
632 IS=INSTR(TXT$,"@"):IF IS=0 THEN 640ELSE A$=MID$(TXT$,IS+1,3)
633 GET 2,VAL(A$):IG$=LEFT$(I$,INSTR(I$+";",";")-1)
634 TXT$=LEFT$(TXT$,IS-1)+IG$+MID$(TXT$,IS+4):GOTO 632
640 TXT$=REST$+TXT$
641 IF LEN(TXT$)<54 THEN REST$=TXT$:LINE INPUT#1,TXT$:GOTO 631
642 NS=54:FOR NQ=54 TO 1 STEP-1:IF MID$(TXT$,NQ,1)=" "THEN NS=NQ:NQ=-1
643 NEXT:PRT$=LEFT$(TXT$,NS-1):GOSUB 520:TXT$=MID$(TXT$,NS+1):GOTO 641
650 PRT$=REST$:GOSUB 520:PRT$="":GOSUB 520:CLOSE 1:RETURN
700 'Zoeken in bestand naar KZ$
710 N=0:NL=0:ADV=0:OPEN"I",1,DRV$+FILE$
720 LINE INPUT#1,NAAM$:NL=NL+1:IF ASC(NAAM$)<>45 THEN 720
721 IF NAAM$="-einde-"THEN 750
730 INPUT#1,KODE$,SZ$,PM$:IF INSTR(KZ$,KODE$)=0 THEN NL=NL+1:GOTO 720
731 IF SZ$<>"5"AND INSTR(SZ$,CHR$(SZ+48))=0 THEN NL=NL+1:GOTO 720
732 IF KS=0 THEN 740ELSE KS$=MID$(PM$,3,1):IF KS=1 AND KS$="2"THEN KS=-1
733 IF VAL(KS$)=ABS(KS)THEN 740ELSE NL=NL+1:GOTO 720
740 N=N+1:NL(N)=NL:NL=NL+1:IF ASC(KODE$)=ASC(KZ$)THEN ADV=N
741 GOSUB 940:PRINT USING"##: ";N;:PRINT MID$(NAAM$,2)PRMO$
742 IF N<25 THEN 720
750 CLOSE 1:IF N>0 THEN 751ELSE IF KS=0 OR KS=1 THEN RETURN ELSE IF KS=-1 THEN KS=-2:GOTO 700
751 IF KS=-1 THEN KN$="eerste "+KN$ELSE IF KS=2 THEN KN$="tweede "+KN$
752 PRINT" 0: Geen "KN$:PRINT
753 IF ADV<>0 THEN PRINT"CuliCom adviseert nummer"STR$(ADV)".":PRINT
760 IP$="Welk nummer wilt u":GOSUB 920:NR=VAL(A$):IF NR<0 OR NR>N THEN 760
761 RETURN
800 'omzetten hoeveelheid en eenheid IG$
810 IHM=0:IGN=VAL(MID$(IG$,2,3)):GET 2,IGN
820 IE$=MID$(IG$,5,1):IH$=MID$(IG$,6):II=INSTR(IH$,".")
821 IF II=0 THEN 840ELSE IF II=1 THEN IH1$="":GOTO 830
822 IH1$=LEFT$(IH$,II-1)+" ":IH$=MID$(IH$,II)
830 IF IH$=".125"THEN IH$="1/8"
831 IF IH$=".25"THEN IH$="1/4"
832 IF IH$=".3"THEN IH$="1/3"
833 IF IH$=".5"THEN IH$="1/2"
834 IF IH$=".6"THEN IH$="2/3"
835 IF IH$=".75"THEN IH$="3/4"
839 IH$=IH1$+IH$
840 IF IE$="e"THEN IE$="eetlepel":IHM=1
841 IF IE$="t"THEN IE$="theelepel":IHM=1
842 IF IE$="d"THEN IE$="dessertlepel":IHM=1
843 IF IE$="b"THEN IE$="borrelglaasje":IHM=1
844 IF IE$="G"THEN IE$="glas"
845 IF IE$="g"THEN IE$="gram"
846 IF IE$="l"THEN IE$="liter"
847 IF IE$="B"THEN IE$="blikje":IHM=1
848 IF IE$="T"THEN IE$="teentje":IHM=1
849 IF IE$="k"THEN IE$="kopje":IHM=1
850 IF IE$="D"THEN IE$="deciliter"
851 IF IE$="s"THEN IE$="schaal"
852 IF IE$="S"THEN IE$="scheutje":IHM=1
853 IF IE$="K"THEN IE$="krop"
854 IF IE$="q"THEN IE$="klontje":IHM=1
855 IF IE$="z"THEN IE$="schijfje":IHM=1
856 IF IE$="Q"THEN IE$="takje":IHM=1
860 IF IE$="/"THEN IE$="":GOTO 862ELSE IF IE$=" "THEN 862
861 IF IHM=1 AND II=0 AND IH$<>"1" THEN IE$=" "+IE$+"s "ELSE IE$=" "+IE$+" "
862 IG$=IH$+IE$:IG$=STRING$(20-LEN(IG$),32)+IG$+" "+LEFT$(I$,INSTR(I$+";",";")-1)
870 RETURN
900 'diverse subroutines
901 'omzetten a$ naar lowercase
902 FOR NQ=1 TO LEN(A$):MID$(A$,NQ,1)=CHR$(ASC(MID$(A$,NQ))OR 32):NEXT:RETURN
910 'scherm wissen
911 FOR NQ=1 TO 25:PRINT:NEXT:RETURN
920 'input-routine
921 PRINT IP$;:IF DF$<>""THEN PRINT" ("DF$")";
922 PRINT TAB(50)"? ";:LINE INPUT A$:IF A$=""THEN A$=DF$
923 IF A$=""THEN 920ELSE DF$="":RETURN
930 'terug naar keuzelijst
931 PRINT"Toets Return om terug te gaan naar de keuzelijst ... ";:A$=INKEY$
932 A$=INPUT$(1):PRINT:GOTO 100
940 'omzetten ko$
941 ON ASC(PM$)-96 GOTO 942,943,944
942 PRMO$=" (goedkoop, ":GOTO 945
943 PRMO$=" (niet zo duur, ":GOTO 945
944 PRMO$=" (duur, "
945 ON ASC(MID$(PM$,2))-96 GOTO 946,947,948
946 PRMO$=PRMO$+"gemakkelijk)":GOTO 949
947 PRMO$=PRMO$+"bewerkelijk)":GOTO 949
948 PRMO$=PRMO$+"moeilijk)
949 RETURN
1000 'Menu kiezen naar hoofdingredient
1010 GOSUB 910:PRINT"CuliCom menukeuze naar hoofdingredient"STRING$(74-POS(0),"-")"[H-S]
1011 PRINT:PRINT:PRINT
1020 IP$="Hoofdingredient":GOSUB 920:GOSUB 900:HBD$=A$
1040 PRINT:PRINT:PRINT"U kunt kiezen uit de volgende hoofdgerechten:":PRINT
1090 N=0:NL=0
1100 OPEN"I",1,DRV$+HFD$
1110 LINE INPUT#1,NAAM$:NL=NL+1:IF ASC(NAAM$)<>45 THEN 1110
1111 IF NAAM$="-einde-"THEN 1200
1120 INPUT#1,HB$,GR$,SZ$,VOOR$,NA$,PM$:LINE INPUT#1,A$
1121 IF HB$<>HBD$THEN NL=NL+1:GOTO 1110
1122 IF SZ$<>"5"AND INSTR(SZ$,CHR$(SZ+48))=0 THEN NL=NL+1:GOTO 1110
1130 N=N+1:NL(N)=NL:NL=NL+1
1131 GOSUB 940:PRINT USING"##: ";N;:PRINT MID$(NAAM$,2)PRMO$
1132 IF N<25 THEN 1110
1200 CLOSE:IF N<>0 THEN 1210
1201 PRINT"CuliCom kent geen recept voor "HBD$" in dit seizoen.
1202 PRINT"Wilt u iets anders invoeren of terug naar de keuzelijst ? (a/k) ";
1203 A$=INPUT$(1):IF A$="A"OR A$="a"THEN PRINT:GOTO 1000
1204 IF A$="K"OR A$="k"THEN PRINT:GOTO 100ELSE 1203
1210 PRINT" 0: Terug naar keuzelijst":PRINT
1211 IP$="Welk nummer wilt u":GOSUB 920:NR=VAL(A$):IF NR<0 OR NR>N THEN 1211
1212 IF NR=0 THEN 100ELSE NLH=NL(NR):GOTO 10000
2000 'Menu kiezen naar soort (vlees/vis/enz.)
2010 GOSUB 910:PRINT"CuliCom menukeuze naar soort"STRING$(74-POS(0),"-")"[H-S]
2011 PRINT:PRINT:PRINT"U kunt kiezen uit:
2012 PRINT
2020 PRINT" 1: Vis & schaaldieren
2021 PRINT" 2: Vlees
2022 PRINT" 3: Vegetarisch
2023 PRINT" 4: Wild & gevogelte
2024 PRINT" 5: Pasta & rijst
2029 PRINT" 0: Terug naar keuzelijst":PRINT
2030 IP$="Welk nummer wilt u":GOSUB 920:NR=VAL(A$):IF NR<0 OR NR>5 THEN 2030
2031 IF NR=0 THEN 100ELSE NR$=CHR$(48+NR)
2040 PRINT:PRINT:PRINT"U kunt kiezen uit de volgende hoofdgerechten:":PRINT
2090 N=0:NL=0
2100 OPEN"I",1,DRV$+HFD$
2110 LINE INPUT#1,NAAM$:NL=NL+1:IF ASC(NAAM$)<>45 THEN 2110
2111 IF NAAM$="-einde-"THEN 2200
2120 INPUT#1,HB$,GR$,SZ$,VOOR$,NA$,PM$:LINE INPUT#1,A$
2121 IF MID$(PM$,3,1)<>NR$THEN NL=NL+1:GOTO 2110
2122 IF SZ$<>"5"AND INSTR(SZ$,CHR$(SZ+48))=0 THEN NL=NL+1:GOTO 2110
2130 N=N+1:NL(N)=NL:NL=NL+1
2131 GOSUB 940:PRINT USING"##: ";N;:PRINT MID$(NAAM$,2)PRMO$
2132 IF N<25 THEN 2110
2200 CLOSE:IF N<>0 THEN 2210
2201 PRINT"CuliCom ken geen toepasselijk recept voor dit seizoen.
2202 PRINT"Wilt u iets anders invoeren of terug naar de keuzelijst ? (a/k) ";
2203 A$=INPUT$(1):IF A$="A"OR A$="a"THEN PRINT:GOTO 2000
2204 IF A$="K"OR A$="k"THEN PRINT:GOTO 100ELSE 2203
2210 PRINT" 0: Terug naar keuzelijst":PRINT
2211 IP$="Welk nummer wilt u":GOSUB 920:NR=VAL(A$):IF NR<0 OR NR>N THEN 2211
2212 IF NR=0 THEN 100ELSE NLH=NL(NR):GOTO 10000
3000 '
10000 'Hoofdgerecht gekozen -> rest uitzoeken
10010 OPEN"I",1,DRV$+HFD$:IGH=0:OPEN"R",2,DRV$+IGF$,30:FIELD 2,30AS I$
10011 FOR NX=1 TO NLH:LINE INPUT#1,A$:NEXT
10012 INPUT#1,HBD$,GR$,SZ$,VOOR$,NA$,PM$,FEC$,WIJN$:PRINT:PRINT
10013 PRINT"Voor dit gerecht heeft u de volgende ingredienten nodig:":PRINT
10020 LINE INPUT#1,IG$:IF ASC(IG$)<>64 THEN 10030
10021 IGH=IGH+1:GOSUB 800:PRINT IG$:GOTO 10020
10030 CLOSE 1:PRINT
10031 PRINT"Wilt u verdergaan of terug naar de keuzelijst ? (v/k) ";
10032 A$=INPUT$(1):IF A$="K"OR A$="k"THEN PRINT:GOTO 100
10033 IF A$<>"V"AND A$<>"v"THEN 10032ELSE PRINT"v"
10100 IF FEC$="-"THEN NLF=0:GOTO 11000
10110 PRINT:PRINT:PRINT"U kunt uit de volgende feculenten kiezen:"
10120 N=0:PRINT:FOR NN=1 TO 25:A$=CHR$(96+NN)
10121 IF INSTR(FEC$,A$)=0 AND INSTR(FEC$,"+")=0 OR FEC$(NN)=""THEN 10130
10122 N=N+1:NL(N)=NN:IF ASC(FEC$)=ASC(A$)THEN ADV=N
10123 PRINT USING"##: ";N;:PRINT FEC$(NN)
10130 NEXT NN:PRINT" 0: Geen feculenten":PRINT
10131 IF ADV<>0 THEN PRINT"CuliCom adviseert nummer"STR$(ADV)".":PRINT
10140 IP$="Welk nummer wilt u":GOSUB 920:NR=VAL(A$):IF NR<0 OR NR>N THEN 10140
10141 IF NR=0 THEN NLF=0ELSE NLF=NL(NR)
11000 'Groente kiezen
11010 PRINT:PRINT:PRINT"U kunt uit de volgende groenten kiezen:"
11020 PRINT:FILE$=GRF$:KZ$=GR$:KN$="groente":KS=0:GOSUB 700
11100 IF N<>0 THEN 11110
11101 PRINT"CuliCom kent geen bijbehorende groente voor dit seizoen.
11102 GOTO 930
11110 IF NR=0 THEN NLG=0ELSE NLG=NL(NR)
12000 'Voorgerecht kiezen
12010 PRINT:PRINT:PRINT"U kunt uit de volgende voorgerechten kiezen:"
12020 PRINT:FILE$=VRF$:KZ$=VOOR$:KN$="voorgerecht":KS=1:GOSUB 700
12100 IF N<>0 THEN 12110
12101 PRINT"CuliCom kent geen bijbehorend voorgerecht voor dit seizoen.
12102 GOTO 930
12110 IF NR=0 THEN NLV=0ELSE NLV=NL(NR)
12200 IF KS=1 OR KS=-2 THEN NLW=0:GOTO 13000
12210 PRINT:PRINT:PRINT"U kunt uit de volgende voorgerechten kiezen:"
12220 PRINT:FILE$=VRF$:KZ$=VOOR$:KN$="voorgerecht":KS=2:GOSUB 700
12300 IF N<>0 THEN 12310
12301 PRINT"CuliCom kent geen bijbehorend voorgerecht voor dit seizoen.
12302 GOTO 930
12310 IF NR=0 THEN NLW=0ELSE NLW=NL(NR)
13000 'Nagerecht kiezen
13010 PRINT:PRINT:PRINT"U kunt uit de volgende nagerechten kiezen:"
13020 PRINT:FILE$=NAF$:KZ$=NA$:KN$="nagerecht":KS=0:GOSUB 700
13100 IF N<>0 THEN 13110
13101 PRINT"CuliCom kent geen bijbehorend nagerecht voor dit seizoen.
13102 GOTO 930
13110 IF NR=0 THEN NLN=0ELSE NLN=NL(NR)
20000 'Afdrukken menukaart
20005 PRINT:PRINT
20010 IP$="Hoeveel menukaarten wilt u":DF$="1":GOSUB 920
20011 IF VAL(A$)<1 OR VAL(A$)>10 THEN 20010ELSE COUNT=VAL(A$)
20020 PRINT:PRINT"Toets Return als de printer klaar staat ... ";:A$=INKEY$
20021 A$=INPUT$(1):PRINT
20022 PRINT:PRINT"Het menu wordt nu afgedrukt.
20040 WHILE COUNT<>0
20050 GOSUB 500
20100 PRT$=" ##      ##":GOSUB 520
20101 PRT$=" ####  ####":GOSUB 520
20102 PRT$=" ##  ##  ##      ######      ########      ##      ##":GOSUB 520
20103 PRT$=" ##      ##    ##      ##    ##      ##    ##      ##":GOSUB 520
20104 PRT$=" ##      ##    ########      ##      ##    ##      ##":GOSUB 520
20105 PRT$=" ##      ##    ##            ##      ##    ##      ##":GOSUB 520
20106 PRT$=" ##      ##      #######     ##      ##      ########":GOSUB 520
20110 PRT$="":GOSUB 520:GOSUB 520
20111 PRT$="voor"+DATUM$:PRT$=STRING$(27-LEN(PRT$)/2,32)+PRT$:GOSUB 520
20112 PRT$="":GOSUB 520:GOSUB 520
20120 PRT$=STRING$(54,"="):GOSUB 520
20121 PRT$="Een CuliCom menu met "+HBD$:PRT$=STRING$(27-LEN(PRT$)/2,32)+PRT$
20122 GOSUB 520:PRT$=STRING$(54,"="):GOSUB 520
20123 PRT$="":GOSUB 520:GOSUB 520:GOSUB 520
20130 IF NLV=0 THEN 20135ELSE FILE$=VRF$:NL=NLV:GOSUB 550:GOSUB 560
20135 IF NLW=0 THEN 20140ELSE FILE$=VRF$:NL=NLW:GOSUB 550:GOSUB 560
20140 FILE$=HFD$:NL=NLH:GOSUB 550
20141 IF NLF=0 THEN GOTO 20150
20142 A$=FEC$(NLF):GOSUB 900:PRT$="Geserveerd met "+A$
20143 PRT$=STRING$(27-LEN(PRT$)/2,32)+PRT$:GOSUB 520
20144 PRT$="":GOSUB 520
20150 IF NLG=0 THEN 20160ELSE GOSUB 560:FILE$=GRF$:NL=NLG:GOSUB 550
20160 IF NLN=0 THEN 20200ELSE GOSUB 560:FILE$=NAF$:NL=NLN:GOSUB 550
20200 'Wijnsuggestie
20205 IF ASC(WIJN$)=44 THEN 20240
20210 WIJN$=","+WIJN$+",":OPEN"I",1,DRV$+WNF$:NL=INT(RND*101)
20211 FOR NX=1 TO NL:LINE INPUT#1,A$:NEXT
20220 IF EOF(1)THEN CLOSE 1:OPEN"I",1,DRV$+WNF$:GOTO 20220ELSE LINE INPUT#1,NAAM$
20221 IF VAL(LEFT$(NAAM$,4))=0 THEN 20220
20222 IF INSTR(26,NAAM$,WIJN$)=0 THEN 20220
20230 CLOSE 1:WN$=MID$(NAAM$,5,22)
20231 WN$=LEFT$(WN$,INSTR(WN$,",")-1)+"."
20240 PRT$="":GOSUB 520:GOSUB 520
20241 PRT$=STRING$(22,32)+STRING$(10,"*"):GOSUB 520
20250 PRT$="Wijnsuggestie bij dit menu: "+WN$
20251 PRT$=STRING$(27-LEN(PRT$)/2,32)+PRT$:GOSUB 520
20252 PRT$=STRING$(22,32)+STRING$(10,"*"):GOSUB 520
20300 GOSUB 530
20310 COUNT=COUNT-1:WEND
21000 'Afdrukken recepten
21010 GOSUB 500:PRTP=1
21025 IF NLV=0 THEN 21030ELSE FILE$=VRF$:NL=NLV:GOSUB 600:GOSUB 540
21030 IF NLW=0 THEN 21035ELSE FILE$=VRF$:NL=NLW:GOSUB 600:GOSUB 540
21035 FILE$=HFD$:NL=NLH:GOSUB 600
21036 IF NLF=0 THEN 21040
21037 A$=FEC$(NLF):GOSUB 900:PRT$="Serveren met "+A$
21038 GOSUB 520:PRT$="":GOSUB 520
21040 IF NLG=0 THEN 21050ELSE GOSUB 540
21045 FILE$=GRF$:NL=NLG:GOSUB 600
21050 IF NLN=0 THEN 21100ELSE GOSUB 540
21055 FILE$=NAF$:NL=NLN:GOSUB 600
21100 GOSUB 530:CLOSE:GOTO 300